Begin new Asset Pipeline

src/engine/StagingBuffer.zig

@@ -0,0 +1,54 @@
+const StagingBuffer = @This();
+const std = @import("std");
+
+const vk = @import("vulkan");
+
+const Engine = @import("Engine.zig");
+
+buffer: vk.Buffer,
+memory: vk.DeviceMemory,
+
+pub fn init(engine: *Engine, data: []const u8, destination_queue_family: u32) !StagingBuffer {
+    const transfer_queue_family = engine.transfer_queue.allocation.family;
+
+    const single_queue_family = transfer_queue_family == destination_queue_family;
+    const queue_family_indices: []const u32 = if (single_queue_family) &.{} else &.{ transfer_queue_family, destination_queue_family };
+
+    const buffer = try engine.device.createBuffer(&.{
+        .size = data.len,
+        .usage = .{
+            .transfer_src_bit = true,
+        },
+        .sharing_mode = if (single_queue_family) .exclusive else .concurrent,
+        .p_queue_family_indices = queue_family_indices.ptr,
+    }, null);
+    errdefer engine.device.destroyBuffer(buffer);
+
+    const memory_requirements = engine.device.getBufferMemoryRequirements(buffer);
+    const memory = try engine.allocate(
+        memory_requirements,
+        .{
+            .host_visible_bit = true,
+            .host_coherent_bit = true,
+        },
+    );
+    errdefer engine.device.freeMemory(memory, &engine.vk_allocator.interface);
+
+    try engine.device.bindBufferMemory(buffer, memory, 0);
+
+    const mapped_memory: [*]u8 = @ptrCast(try engine.device.mapMemory(memory, 0, data.len, .{}) orelse return error.OutOfMemory);
+    defer engine.device.unmapMemory(memory);
+    @memcpy(mapped_memory, data);
+
+    return .{
+        .buffer = buffer,
+        .memory = memory,
+    };
+}
+
+pub fn deinit(self: *StagingBuffer, engine: *Engine) void {
+    engine.device.freeMemory(self.memory, &engine.vk_allocator.interface);
+    engine.device.destroyBuffer(self.buffer);
+
+    self.* = undefined;
+}